########################################################
# Please file all bug reports, patches, and feature
# requests under:
#      https://sourceforge.net/p/logwatch/_list/tickets
# Help requests and discusion can be filed under:
#      https://sourceforge.net/p/logwatch/discussion/
########################################################

#####################################################
## Copyright (c) 2008 Kirk Bauer
## Covered under the included MIT/X-Consortium License:
##    http://www.opensource.org/licenses/mit-license.php
## All modifications and contributions by other persons to
## this script are assumed to have been donated to the
## Logwatch project and thus assume the above copyright
## and licensing terms.  If you want to make contributions
## under your own copyright or a different license this
## must be explicitly stated in the contribution an the
## Logwatch project reserves the right to not accept such
## contributions.  If you have made significant
## contributions to this script and want to claim
## copyright please contact logwatch-devel@lists.sourceforge.net.
#########################################################
use strict;
#my $Detail = $ENV{'LOGWATCH_DETAIL_LEVEL'} || 0;
#Init String Containers
my ( $Module, $Reason);
#Init Hashes
my (
%AlreadyLoaded,     %ErrorInsert,   %ErrorInstall,
%Modules,           %OtherList
);
while (defined(my $ThisLine = <STDIN>)) {
   chomp($ThisLine);
   if ( $ThisLine =~ s/^modprobe: Can\'t locate module ([\w-]+)\s*$/$1/ ) {
      $Modules{$ThisLine}++;
   } elsif ( $ThisLine =~ s/^FATAL: Module (.*) not found./$1/) {
      $Modules{$ThisLine}++;
   } elsif ( $ThisLine =~ s/^FATAL: Could not load (.*): No such file or directory/$1/) {
      $Modules{$ThisLine}++;
   } elsif ( (undef,$Module,$Reason) = ( $ThisLine =~ /(WARNING|FATAL): Error inserting ([^ ]* \([^ ]*\)): (.*)$/ ) ) {
      $ErrorInsert{$Module}{$Reason}++;
   } elsif ( (undef,$Module) = ( $ThisLine =~ /(WARNING|FATAL): Error running install command for (.*)$/ ) ) {
      $ErrorInstall{$Module}++;
   } elsif ( (undef,$Module) = ( $ThisLine =~ /(WARNING|FATAL): Module ([^ ]*) already in kernel./ ) ) {
      $AlreadyLoaded{$Module}++;
   } else {
      $OtherList{$ThisLine}++;
   }
}

if (keys %Modules) {
   print "\nCan't locate these modules:\n";
   foreach my $ThisOne (sort keys %Modules) {
      print "   " . $ThisOne . ": " . $Modules{$ThisOne} . " Time(s)\n";
   }
}

if (keys %ErrorInsert) {
   print "\nErrors inserting modules:\n";
   foreach my $Module (sort {$a cmp $b} keys %ErrorInsert) {
      print "   $Module :\n";
      foreach my $Reason (sort {$a cmp $b} keys %{$ErrorInsert{$Module}}) {
         print "      $Reason : $ErrorInsert{$Module}{$Reason} Time(s)\n";
      }
   }
}

if (keys %ErrorInstall) {
   print "\nErrors running install command:\n";
   foreach my $Module (sort {$a cmp $b} keys %ErrorInstall) {
      print "   $Module : $ErrorInstall{$Module} Time(s)\n";
   }
}

if (keys %AlreadyLoaded) {
   print "\nModules already in kernel:\n";
   foreach my $Module (sort {$a cmp $b} keys %AlreadyLoaded) {
      print "   $Module : $AlreadyLoaded{$Module} Time(s)\n";
   }
}

if (keys %OtherList) {
   print "\n**Unmatched Entries**\n";
   foreach my $line (sort {$a cmp $b} keys %OtherList) {
      print "$line: $OtherList{$line} Time(s)\n";
   }
}

exit(0);

# vi: shiftwidth=3 tabstop=3 syntax=perl et
# Local Variables:
# mode: perl
# perl-indent-level: 3
# indent-tabs-mode: nil
# End: